Contract Source Code (Solidity Standard Json-Input format)

IDE

• Blockscan IDE

More Options

• Similar
• Submit Audit
• Compare

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import { OwnableUpgradeable } from "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";

import { ISubOracle } from "../../interfaces/oracle/ISubOracle.sol";

/// @title Beefy Oracle
/// @author Beefy, @kexley
/// @notice On-chain oracle using various sources
contract BeefyOracle is OwnableUpgradeable {

    /// @dev Struct for the latest price of a token with the timestamp
    /// @param price Stored price
    /// @param timestamp Last update timestamp
    struct LatestPrice {
        uint256 price;
        uint256 timestamp;
    }

    /// @dev Struct for delegating the price calculation to a library using stored data
    /// @param oracle Address of the library for a particular oracle type
    /// @param data Stored data for calculating the price of a specific token using the library
    struct SubOracle {
        address oracle;
        bytes data;
    }

    /// @notice Latest price of a token with a timestamp
    mapping(address => LatestPrice) public latestPrice;

    /// @notice Oracle library address and payload for delegating the price calculation of a token
    mapping(address => SubOracle) public subOracle;

    /// @notice Length of time in seconds before a price goes stale
    uint256 public staleness;

    /// @notice Price of a token has been updated
    /// @param token Token address
    /// @param price New price
    /// @param timestamp Timestamp of price fetch
    event PriceUpdated(address indexed token, uint256 price, uint256 timestamp);

    /// @notice New oracle has been set
    /// @param token Token address
    /// @param oracle Library address for price fetch
    /// @param data Data to pass to library to calculate the price for that token
    event SetOracle(address indexed token, address oracle, bytes data);

    /// @notice New staleness has been set
    /// @param staleness Length of time a price stays fresh for
    event SetStaleness(uint256 staleness);

    /// @notice Initialize the contract
    /// @dev Ownership is transferred to msg.sender
    function initialize() external initializer {
        __Ownable_init();
    }

    /// @notice Fetch the most recent stored price for a token
    /// @param _token Address of the token being fetched
    /// @return price Price of the token
    function getPrice(address _token) external view returns (uint256 price) {
        price = latestPrice[_token].price;
    }

    /// @notice Fetch an updated price for a token
    /// @param _token Address of the token being fetched
    /// @return price Updated price of the token
    /// @return success Price update was success or not
    function getFreshPrice(address _token) external returns (uint256 price, bool success) {
        (price, success) = _getFreshPrice(_token);
    }

    /// @dev If the price is stale then calculate a new price by delegating to the sub oracle
    /// @param _token Address of the token being fetched
    /// @return price Updated price of the token
    /// @return success Price update was success or not
    function _getFreshPrice(address _token) private returns (uint256 price, bool success) {
        if (latestPrice[_token].timestamp + staleness > block.timestamp) {
            price = latestPrice[_token].price;
            success = true;
        } else {
            (price, success) = ISubOracle(subOracle[_token].oracle).getPrice(subOracle[_token].data);
            if (success) {
                latestPrice[_token] = LatestPrice({price: price, timestamp: block.timestamp});
                emit PriceUpdated(_token, price, block.timestamp);
            }
        }
    }

    /* ----------------------------------- OWNER FUNCTIONS ----------------------------------- */

    /// @notice Owner function to set a sub oracle and data for a token
    /// @dev The payload will be validated against the library
    /// @param _token Address of the token being fetched
    /// @param _oracle Address of the library used to calculate the price
    /// @param _data Payload specific to the token that will be used by the library
    function setOracle(address _token, address _oracle, bytes calldata _data) external onlyOwner {
        _setOracle(_token, _oracle, _data);
    }

    /// @notice Owner function to set a sub oracle and data for an array of tokens
    /// @dev The payloads will be validated against the libraries
    /// @param _tokens Addresses of the tokens being fetched
    /// @param _oracles Addresses of the libraries used to calculate the price
    /// @param _datas Payloads specific to the tokens that will be used by the libraries
    function setOracles(
        address[] calldata _tokens,
        address[] calldata _oracles,
        bytes[] calldata _datas
    ) external onlyOwner {
        uint256 tokenLength = _tokens.length;
        for (uint i; i < tokenLength;) {
            _setOracle(_tokens[i], _oracles[i], _datas[i]);
            unchecked { ++i; }
        }
    }

    /// @dev Set the sub oracle and data for a token, it also validates that the data is correct
    /// @param _token Address of the token being fetched
    /// @param _oracle Address of the library used to calculate the price
    /// @param _data Payload specific to the token that will be used by the library
    function _setOracle(address _token, address _oracle, bytes calldata _data) private {
        ISubOracle(_oracle).validateData(_data);
        subOracle[_token] = SubOracle({oracle: _oracle, data: _data});
        _getFreshPrice(_token);
        emit SetOracle(_token, _oracle, _data);
    }

    /// @notice Owner function to set the staleness
    /// @param _staleness Length of time in seconds before a price becomes stale
    function setStaleness(uint256 _staleness) external onlyOwner {
        staleness = _staleness;
        emit SetStaleness(_staleness);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/ContextUpgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract OwnableUpgradeable is Initializable, ContextUpgradeable {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    function __Ownable_init() internal onlyInitializing {
        __Ownable_init_unchained();
    }

    function __Ownable_init_unchained() internal onlyInitializing {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.2;

import "../../utils/AddressUpgradeable.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     * @custom:oz-retyped-from bool
     */
    uint8 private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint8 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
     * constructor.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        bool isTopLevelCall = !_initializing;
        require(
            (isTopLevelCall && _initialized < 1) || (!AddressUpgradeable.isContract(address(this)) && _initialized == 1),
            "Initializable: contract is already initialized"
        );
        _initialized = 1;
        if (isTopLevelCall) {
            _initializing = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: setting the version to 255 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint8 version) {
        require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
        _initialized = version;
        _initializing = true;
        _;
        _initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        require(!_initializing, "Initializable: contract is initializing");
        if (_initialized != type(uint8).max) {
            _initialized = type(uint8).max;
            emit Initialized(type(uint8).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint8) {
        return _initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _initializing;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library AddressUpgradeable {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

interface ISubOracle {
    function getPrice(bytes calldata data) external returns (uint256 price, bool success);
    function validateData(bytes calldata data) external view;
}

{
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "evmVersion": "paris",
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  },
  "libraries": {}
}

[{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint8","name":"version","type":"uint8"}],"name":"Initialized","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"previousOwner","type":"address"},{"indexed":true,"internalType":"address","name":"newOwner","type":"address"}],"name":"OwnershipTransferred","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"token","type":"address"},{"indexed":false,"internalType":"uint256","name":"price","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"timestamp","type":"uint256"}],"name":"PriceUpdated","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"token","type":"address"},{"indexed":false,"internalType":"address","name":"oracle","type":"address"},{"indexed":false,"internalType":"bytes","name":"data","type":"bytes"}],"name":"SetOracle","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint256","name":"staleness","type":"uint256"}],"name":"SetStaleness","type":"event"},{"inputs":[{"internalType":"address","name":"_token","type":"address"}],"name":"getFreshPrice","outputs":[{"internalType":"uint256","name":"price","type":"uint256"},{"internalType":"bool","name":"success","type":"bool"}],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"_token","type":"address"}],"name":"getPrice","outputs":[{"internalType":"uint256","name":"price","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"initialize","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"","type":"address"}],"name":"latestPrice","outputs":[{"internalType":"uint256","name":"price","type":"uint256"},{"internalType":"uint256","name":"timestamp","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"owner","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"renounceOwnership","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"_token","type":"address"},{"internalType":"address","name":"_oracle","type":"address"},{"internalType":"bytes","name":"_data","type":"bytes"}],"name":"setOracle","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address[]","name":"_tokens","type":"address[]"},{"internalType":"address[]","name":"_oracles","type":"address[]"},{"internalType":"bytes[]","name":"_datas","type":"bytes[]"}],"name":"setOracles","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"_staleness","type":"uint256"}],"name":"setStaleness","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"staleness","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"","type":"address"}],"name":"subOracle","outputs":[{"internalType":"address","name":"oracle","type":"address"},{"internalType":"bytes","name":"data","type":"bytes"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"newOwner","type":"address"}],"name":"transferOwnership","outputs":[],"stateMutability":"nonpayable","type":"function"}]

0x608060405234801561001057600080fd5b50600436106100b45760003560e01c8063715018a611610071578063715018a6146101755780637eb0324e1461017d5780638129fc1c1461019e5780638da5cb5b146101a6578063baeb325b146101c1578063f2fde38b146101e957600080fd5b80630cc44887146100b957806341976e09146100d557806352749a39146100fe57806353084eff14610113578063644a2f9e1461014f5780636d64a42014610162575b600080fd5b6100c260675481565b6040519081526020015b60405180910390f35b6100c26100e336600461092f565b6001600160a01b031660009081526065602052604090205490565b61011161010c36600461099d565b6101fc565b005b61013a61012136600461092f565b6065602052600090815260409020805460019091015482565b604080519283526020830191909152016100cc565b61011161015d366004610a37565b61029c565b610111610170366004610a50565b6102e0565b6101116102fa565b61019061018b36600461092f565b61030e565b6040516100cc929190610ade565b6101116103bd565b6033546040516001600160a01b0390911681526020016100cc565b6101d46101cf36600461092f565b6104cf565b604080519283529015156020830152016100cc565b6101116101f736600461092f565b6104e5565b61020461055b565b8460005b818110156102925761028a88888381811061022557610225610b3d565b905060200201602081019061023a919061092f565b87878481811061024c5761024c610b3d565b9050602002016020810190610261919061092f565b86868581811061027357610273610b3d565b90506020028101906102859190610b53565b6105b5565b600101610208565b5050505050505050565b6102a461055b565b60678190556040518181527f779814184804e11dd965da17b223942318b12cddc906fd8b3801caac5e235d31906020015b60405180910390a150565b6102e861055b565b6102f4848484846105b5565b50505050565b61030261055b565b61030c6000610704565b565b606660205260009081526040902080546001820180546001600160a01b03909216929161033a90610b9a565b80601f016020809104026020016040519081016040528092919081815260200182805461036690610b9a565b80156103b35780601f10610388576101008083540402835291602001916103b3565b820191906000526020600020905b81548152906001019060200180831161039657829003601f168201915b5050505050905082565b600054610100900460ff16158080156103dd5750600054600160ff909116105b806103f75750303b1580156103f7575060005460ff166001145b61045f5760405162461bcd60e51b815260206004820152602e60248201527f496e697469616c697a61626c653a20636f6e747261637420697320616c72656160448201526d191e481a5b9a5d1a585b1a5e995960921b60648201526084015b60405180910390fd5b6000805460ff191660011790558015610482576000805461ff0019166101001790555b61048a610756565b80156104cc576000805461ff0019169055604051600181527f7f26b83ff96e1f2b6a682f133852f6798a09c465da95921460cefb3847402498906020016102d5565b50565b6000806104db83610785565b9094909350915050565b6104ed61055b565b6001600160a01b0381166105525760405162461bcd60e51b815260206004820152602660248201527f4f776e61626c653a206e6577206f776e657220697320746865207a65726f206160448201526564647265737360d01b6064820152608401610456565b6104cc81610704565b6033546001600160a01b0316331461030c5760405162461bcd60e51b815260206004820181905260248201527f4f776e61626c653a2063616c6c6572206973206e6f7420746865206f776e65726044820152606401610456565b6040516329bfe8db60e21b81526001600160a01b0384169063a6ffa36c906105e39085908590600401610bfd565b60006040518083038186803b1580156105fb57600080fd5b505afa15801561060f573d6000803e3d6000fd5b505050506040518060400160405280846001600160a01b0316815260200183838080601f01602080910402602001604051908101604052809392919081815260200183838082843760009201829052509390945250506001600160a01b038781168252606660209081526040909220845181546001600160a01b03191692169190911781559083015190915060018201906106aa9082610c80565b509050506106b784610785565b5050836001600160a01b03167f7c6299bd41834a522ee9008a6594b4a4e41dcb09d7b903f6c1287189dfa75e6f8484846040516106f693929190610d40565b60405180910390a250505050565b603380546001600160a01b038381166001600160a01b0319831681179093556040519116919082907f8be0079c531659141344cd1fd0a4f28419497f9722a3daafe3b4186f6b6457e090600090a35050565b600054610100900460ff1661077d5760405162461bcd60e51b815260040161045690610d6e565b61030c6108e3565b6067546001600160a01b0382166000908152606560205260408120600101549091829142916107b391610db9565b11156107d95750506001600160a01b031660009081526065602052604090205490600190565b6001600160a01b038084166000908152606660205260409081902080549151630d69ba2b60e31b81529190921691636b4dd1589161081d9160010190600401610de0565b60408051808303816000875af115801561083b573d6000803e3d6000fd5b505050506040513d601f19601f8201168201806040525081019061085f9190610e70565b909250905080156108de576040805180820182528381524260208083018281526001600160a01b03881660008181526065845286902094518555905160019094019390935583518681529081019190915290917fb556fac599c3c70efb9ab1fa725ecace6c81cc48d1455f886607def065f3e0c0910160405180910390a25b915091565b600054610100900460ff1661090a5760405162461bcd60e51b815260040161045690610d6e565b61030c33610704565b80356001600160a01b038116811461092a57600080fd5b919050565b60006020828403121561094157600080fd5b61094a82610913565b9392505050565b60008083601f84011261096357600080fd5b50813567ffffffffffffffff81111561097b57600080fd5b6020830191508360208260051b850101111561099657600080fd5b9250929050565b600080600080600080606087890312156109b657600080fd5b863567ffffffffffffffff808211156109ce57600080fd5b6109da8a838b01610951565b909850965060208901359150808211156109f357600080fd5b6109ff8a838b01610951565b90965094506040890135915080821115610a1857600080fd5b50610a2589828a01610951565b979a9699509497509295939492505050565b600060208284031215610a4957600080fd5b5035919050565b60008060008060608587031215610a6657600080fd5b610a6f85610913565b9350610a7d60208601610913565b9250604085013567ffffffffffffffff80821115610a9a57600080fd5b818701915087601f830112610aae57600080fd5b813581811115610abd57600080fd5b886020828501011115610acf57600080fd5b95989497505060200194505050565b60018060a01b03831681526000602060406020840152835180604085015260005b81811015610b1b57858101830151858201606001528201610aff565b506000606082860101526060601f19601f830116850101925050509392505050565b634e487b7160e01b600052603260045260246000fd5b6000808335601e19843603018112610b6a57600080fd5b83018035915067ffffffffffffffff821115610b8557600080fd5b60200191503681900382131561099657600080fd5b600181811c90821680610bae57607f821691505b602082108103610bce57634e487b7160e01b600052602260045260246000fd5b50919050565b81835281816020850137506000828201602090810191909152601f909101601f19169091010190565b602081526000610c11602083018486610bd4565b949350505050565b634e487b7160e01b600052604160045260246000fd5b601f821115610c7b576000816000526020600020601f850160051c81016020861015610c585750805b601f850160051c820191505b81811015610c7757828155600101610c64565b5050505b505050565b815167ffffffffffffffff811115610c9a57610c9a610c19565b610cae81610ca88454610b9a565b84610c2f565b602080601f831160018114610ce35760008415610ccb5750858301515b600019600386901b1c1916600185901b178555610c77565b600085815260208120601f198616915b82811015610d1257888601518255948401946001909101908401610cf3565b5085821015610d305787850151600019600388901b60f8161c191681555b5050505050600190811b01905550565b6001600160a01b0384168152604060208201819052600090610d659083018486610bd4565b95945050505050565b6020808252602b908201527f496e697469616c697a61626c653a20636f6e7472616374206973206e6f74206960408201526a6e697469616c697a696e6760a81b606082015260800190565b80820180821115610dda57634e487b7160e01b600052601160045260246000fd5b92915050565b6000602080835260008454610df481610b9a565b8060208701526040600180841660008114610e165760018114610e3257610e62565b60ff19851660408a0152604084151560051b8a01019550610e62565b89600052602060002060005b85811015610e595781548b8201860152908301908801610e3e565b8a016040019650505b509398975050505050505050565b60008060408385031215610e8357600080fd5b8251915060208301518015158114610e9a57600080fd5b80915050925092905056fea26469706673582212205992eb8e6033da48553f638789b5e975049ed78488fd01845df5aca4084997b164736f6c63430008170033