Contract Source Code:

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.24;

import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "./interfaces/IToken.sol";
import "./interfaces/ILPManager.sol";
import "./interfaces/IManager.sol";

contract Genesis is ReentrancyGuard {
    IManager private Manager;
    IToken private Token;
    ILPManager private LPManager;
    address private Treasury;

    uint256 public rewardsLeft;
    uint256 public startAt;
    uint256 public endAt;
    uint256 private _duration = 1 days;

    uint256 public rewardsPerSec = 1 * 1e18;

    uint256 private _forTreasury = 40;
    uint256 private _forLP = 60;

    uint256 public lastId = 1;

    uint256 constant PRECISION = 1e18;

    struct Pool {
        address token;
        uint256 poolShares;
        uint256 amountDeposited;
        uint256 depositFee;
        uint256 accRewardsPerShare;
        uint256 lastRewardTime;
    }

    struct User {
        uint256 deposited;
        uint256 rewardDebt;
        uint256 pendingReward;
    }

    mapping(uint256 => Pool) public pools;
    mapping(address => mapping(uint256 => User)) public userDetailsByPId;

    constructor(address _manager) {
        Manager = IManager(_manager);
    }

    modifier onlyOwner() {
        require(msg.sender == Manager.owner(), "Not Authorized");
        _;
    }

    function setManager(address _manager) external onlyOwner {
        Manager = IManager(_manager);
    }

    function createPool(
        address token,
        uint256 shares,
        uint256 fee
    ) external onlyOwner {
        pools[lastId] = Pool(token, shares, 0, fee, 0, 0);
        lastId++;
    }

    function modifyPool(
        uint256 id,
        uint256 shares,
        uint256 fee
    ) external onlyOwner {
        Pool storage pool = pools[id];
        pool.poolShares = shares;
        pool.depositFee = fee;
    }

    function setProportions(uint256 _tresury, uint256 _lp) external onlyOwner {
        _forTreasury = _tresury;
        _forLP = _lp;
    }

    function setRewardsPerSec(uint256 _rewardsPerSec) external onlyOwner {
        rewardsPerSec = _rewardsPerSec;
    }

    function setAll() external onlyOwner {
        Token = IToken(_getContract("Token"));
        LPManager = ILPManager(_getContract("LPManager"));
        Treasury = _getContract("Treasury");
    }

    function sendPremint(uint256 amount) external onlyOwner {
        Token.transferFrom(msg.sender, address(this), amount);
        rewardsLeft += amount;
    }

    function start() external onlyOwner {
        startAt = block.timestamp;
        endAt = startAt + _duration;
    }

    function deposit(uint256 id, uint256 amount) external nonReentrant {
        require(startAt != 0 && block.timestamp < endAt, "genesis is closed");
        _updatePool(id);

        User storage user = userDetailsByPId[msg.sender][id];
        uint256 _pending = pendingReward(msg.sender, id);
        if (_pending > 0) {
            user.pendingReward += _pending;
        }

        Pool storage pool = pools[id];
        uint256 fee = (amount * pool.depositFee) / 100;
        uint256 amountAfterFee = amount - fee;

        pool.amountDeposited += amountAfterFee;
        user.deposited += amountAfterFee;

        user.rewardDebt =
            (user.deposited * pool.accRewardsPerShare) /
            PRECISION;

        IToken(pool.token).transferFrom(msg.sender, address(this), amount);

        if (fee > 0) {
            uint256 feeTreasury = (fee * _forTreasury) / 100;
            uint256 feeLP = (fee * _forLP) / 100;
            IToken(pool.token).transfer(Treasury, feeTreasury);
            IToken(pool.token).transfer(address(LPManager), feeLP);
            // LPManager.addLiquidity(pool.token);
        }
    }

    function withdraw(uint256 id, uint256 amount) external nonReentrant {
        _updatePool(id);

        User storage user = userDetailsByPId[msg.sender][id];
        require(user.deposited >= amount, "Not enough deposited");

        uint256 _pending = pendingReward(msg.sender, id);
        if (_pending > 0) {
            user.pendingReward += _pending;
        }

        Pool storage pool = pools[id];
        unchecked {
            pool.amountDeposited -= amount;
            user.deposited -= amount;
        }

        user.rewardDebt =
            (user.deposited * pool.accRewardsPerShare) /
            PRECISION;

        IToken(pool.token).transfer(msg.sender, amount);
    }

    function claim(uint256 id) external nonReentrant {
        _updatePool(id);

        User storage user = userDetailsByPId[msg.sender][id];
        uint256 rewards = pendingReward(msg.sender, id) + user.pendingReward;
        user.pendingReward = 0;
        require(rewards > 0, "Nothing to claim");
        rewards = rewardsLeft > rewards ? rewards : rewardsLeft;

        user.rewardDebt =
            (user.deposited * pools[id].accRewardsPerShare) /
            PRECISION;

        if (rewardsLeft < rewards) {
            rewardsLeft = 0;
        } else {
            rewardsLeft -= rewards;
        }

        Token.transfer(msg.sender, rewards);
    }

    function claimAll() external nonReentrant {
        uint256 sum = 0;
        for (uint256 i = 1; i < lastId; i++) {
            _updatePool(i);
            User storage user = userDetailsByPId[msg.sender][i];
            uint256 add = pendingReward(msg.sender, i) + user.pendingReward;
            if (add > 0) {
                user.pendingReward = 0;
                sum += add;
                user.rewardDebt =
                    (user.deposited * pools[i].accRewardsPerShare) /
                    PRECISION;
            }
        }

        if (rewardsLeft < sum) {
            sum = rewardsLeft;
            rewardsLeft = 0;
        } else {
            rewardsLeft -= sum;
        }

        Token.transfer(msg.sender, sum);
    }

    function _updatePool(uint256 id) private {
        Pool storage pool = pools[id];
        if (block.timestamp < startAt) {
            return;
        }
        if (pool.lastRewardTime == 0) {
            pool.lastRewardTime = startAt;
        }
        if (block.timestamp <= pool.lastRewardTime) {
            return;
        }
        if (pool.amountDeposited == 0) {
            pool.lastRewardTime = block.timestamp > endAt
                ? endAt
                : block.timestamp;
            return;
        }
        uint256 timePassed = block.timestamp - pool.lastRewardTime;
        if (endAt != 0 && block.timestamp > endAt) {
            if (pool.lastRewardTime >= endAt) {
                timePassed = 0;
            } else {
                timePassed = endAt - pool.lastRewardTime;
            }
        }
        if (timePassed > 0) {
            uint256 poolReward = (timePassed *
                rewardsPerSec *
                pool.poolShares) / 100;
            pool.accRewardsPerShare =
                pool.accRewardsPerShare +
                ((poolReward * PRECISION) / pool.amountDeposited);
            pool.lastRewardTime = block.timestamp > endAt
                ? endAt
                : block.timestamp;
        }
    }

    function pendingReward(
        address userAddr,
        uint256 id
    ) public view returns (uint256) {
        Pool storage pool = pools[id];
        User storage user = userDetailsByPId[userAddr][id];
        uint256 accRewardsPerShare = pool.accRewardsPerShare;
        uint256 lastTime = pool.lastRewardTime;
        if (block.timestamp < startAt) {
            return 0;
        }
        if (lastTime == 0) {
            lastTime = startAt;
        }
        if (block.timestamp > lastTime && pool.amountDeposited != 0) {
            uint256 timePassed = block.timestamp - lastTime;
            if (endAt != 0 && block.timestamp > endAt) {
                if (lastTime >= endAt) {
                    timePassed = 0;
                } else {
                    timePassed = endAt - lastTime;
                }
            }
            uint256 poolReward = (timePassed *
                rewardsPerSec *
                pool.poolShares) / 100;
            accRewardsPerShare =
                accRewardsPerShare +
                ((poolReward * PRECISION) / pool.amountDeposited);
        }
        uint256 accumulated = (user.deposited * accRewardsPerShare) / PRECISION;
        if (accumulated < user.rewardDebt) {
            return 0;
        }
        return accumulated - user.rewardDebt;
    }

    function _getContract(
        string memory contractName
    ) internal view returns (address) {
        return Manager.getContract(contractName);
    }

    function getTotalRewards(address user) external view returns (uint256) {
        uint256 sum = 0;

        for (uint256 i = 1; i < lastId; i++) {
            sum +=
                pendingReward(user, i) +
                userDetailsByPId[user][i].pendingReward;
        }

        return sum;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.24;

interface ILPManager {
    function addLiquidity(address token) external;
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.20;

interface IManager {
    function getContract(string memory name) external view returns (address);
    function owner() external view returns (address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IToken {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);

    function mint(address to, uint256 value) external;

    function burnFrom(address from, uint256 value) external;
}